#!/usr/bin/perl
#
# $Id$
#
# cpustat.pl
# TiChou <tichou@tichou.org>
#

my $version = "1.0";
my $cmdname = (split('/', $0))[-1];

my $rrdlib = "/var/lib/rrd";

use Getopt::Long;
use RRDs;

sub usage($) {
  my $usage = "Usage: $cmdname [options]
Options:
  -f, --file=FILE  specify RRD file (default $rrdlib/cpustat.rrd)

  -h, --help       display this help and exit
  -v, --version    display version

Report bugs to <tichou\@tichou.org>.\n";

  if (shift) {
    print STDOUT $usage;
    exit 0;
  } else {
    print STDERR $usage;
    exit 1;
  }
}

sub version {
  print "$cmdname $version\n";
  exit 0;
}

my $rrdfile = "$rrdlib/cpustat.rrd";

Getopt::Long::Configure ("bundling");
GetOptions("f|file=s"  => \$rrdfile,
           "h|help"    => \&usage,
           "v|version" => \&version) or &usage(0);

if (not -f $rrdfile) {
  RRDs::create $rrdfile, qw(DS:user:COUNTER:600:0:U
                            DS:nice:COUNTER:600:0:U
                            DS:system:COUNTER:600:0:U
                            DS:idle:COUNTER:600:0:U
                            RRA:AVERAGE:0.5:1:288
                            RRA:AVERAGE:0.5:6:336
                            RRA:AVERAGE:0.5:24:360
                            RRA:AVERAGE:0.5:288:365
                            RRA:MIN:0.5:1:288
                            RRA:MIN:0.5:6:336
                            RRA:MIN:0.5:24:360
                            RRA:MIN:0.5:288:365
                            RRA:MAX:0.5:1:288
                            RRA:MAX:0.5:6:336
                            RRA:MAX:0.5:24:360
                            RRA:MAX:0.5:288:365);
  my $error = RRDs::error;
  die "$0: $error\n" if $error;
}

my ($user,$nice,$system,$idle) = ("U") x 4;

open(STAT, "/proc/stat") or die "$0: can't open /proc/stat: $!\n";
while (<STAT>) {
  /^cpu  (\d+) (\d+) (\d+) (\d+)$/ && (($user,$nice,$system,$idle) = ($1,$2,$3,$4));
};
close(STAT);

RRDs::update $rrdfile, "N:$user:$nice:$system:$idle";
my $error = RRDs::error;
die "$0: $error\n" if $error;