#!/usr/bin/perl
#
# $Id$
#
# apache.pl
# TiChou <tichou@tichou.org>
#

my $version = "1.0";
my $cmdname = (split('/', $0))[-1];

my $rrdlib = "/var/lib/rrd";

my $logdir = "/var/log/apache";
my @logs = ("access_log", "images_log", "iis_log", "connect_log", "method_log", "badmethod_log", "user_log", "crawler_log", "ssl_request_log");

my $wc = "/usr/bin/wc";

use Getopt::Long;
use RRDs;

sub usage($) {
  my $usage = "Usage: $cmdname [options]
Options:
  -f, --file=FILE  specify RRD file (default $rrdlib/apache.rrd)

  -h, --help       display this help and exit
  -v, --version    display version

Report bugs to <tichou\@tichou.org>.\n";

  if (shift) {
    print STDOUT $usage;
    exit 0;
  } else {
    print STDERR $usage;
    exit 1;
  }
}

sub version {
  print "$cmdname $version\n";
  exit 0;
}

my $rrdfile = "$rrdlib/apache.rrd";

Getopt::Long::Configure ("bundling");
GetOptions("f|file=s"  => \$rrdfile,
           "h|help"    => \&usage,
           "v|version" => \&version) or &usage(0);

if (not -f $rrdfile) {
  RRDs::create $rrdfile, qw(DS:access:COUNTER:600:0:U
                            DS:images:COUNTER:600:0:U
                            DS:iis:COUNTER:600:0:U
                            DS:connect:COUNTER:600:0:U
                            DS:other:COUNTER:600:0:U
                            DS:bad:COUNTER:600:0:U
                            DS:userdir:COUNTER:600:0:U
                            DS:robots:COUNTER:600:0:U
                            DS:ssl:COUNTER:600:0:U
                            RRA:AVERAGE:0.5:1:288
                            RRA:AVERAGE:0.5:6:336
                            RRA:AVERAGE:0.5:24:360
                            RRA:AVERAGE:0.5:288:365
                            RRA:MIN:0.5:1:288
                            RRA:MIN:0.5:6:336
                            RRA:MIN:0.5:24:360
                            RRA:MIN:0.5:288:365
                            RRA:MAX:0.5:1:288
                            RRA:MAX:0.5:6:336
                            RRA:MAX:0.5:24:360
                            RRA:MAX:0.5:288:365);
  my $error = RRDs::error;
  die "$0: $error\n" if $error;
}

my @result = ();
    
foreach my $log (@logs) {
  my $num = "U";
  open(WC, "$wc -l $logdir/$log|") or die "$0: unable to run $wc: $!\n";
  while (<WC>) {
    /^\s+(\d+)\s+$logdir\/$log$/ && ($num = $1);
  };
  close(WC);
  push(@result, $num);
}

RRDs::update $rrdfile, "N:".join(":", @result);
my $error = RRDs::error;
die "$0: $error\n" if $error;